float ndist = ch("distance");

int isclosed = primintrinsic ( 0, "closed", @primnum );
string polytype = isclosed ? "poly" : "polyline";

int primpts [ ] = primpoints ( 0, @primnum );
vector pos [ ] = { };
foreach ( int pt; primpts )
{
    vector p = point ( 0, "P", pt );
    append ( pos, p );
}

int count = len ( primpts );
int sharedpts = 0;
if ( primpts [ 0 ] != primpts [ -1 ] )
{
    if ( isclosed )
    {
        append ( primpts, primpts [ 0 ] );
        append ( pos, pos [ 0 ] );
    }
}
else
{
    count -= 1;
    if ( !isclosed )
        sharedpts = 1;
}

int newprimpts [ ] = { };
for ( int i = 0; i < count; ++i )
{
    vector p0 = pos [ i ];
    vector p1 = pos [ i + 1 ];
    
    vector pnew0 = lerp ( p0, p1, ndist );
    vector pnew1 = lerp ( p0, p1, 1 - ndist );
    
    int pt0 = addpoint ( 0, pnew0 );
    int pt1 = addpoint ( 0, pnew1 );
    
    append ( newprimpts, primpts [ i ] );
    append ( newprimpts, pt0 );
    append ( newprimpts, pt1 );
}

if ( sharedpts )
    append ( newprimpts, primpts [ 0 ] );

removeprim ( 0, @primnum, 0 );
addprim ( 0, polytype, newprimpts );