string costattrib = chs("costattrib");
string directionattrib = chs("directionattrib");
int usecost = chi("usecost");
float stepsize = ch("stepsize");
float stepsizemultiplier = ch("stepsizemultiplier");
float mindist = ch("mindist");
float maxdist = ch("maxdist");

float dist = stepsize;
float tolerance = 0.0001;

vector pos [ ] = { };
float dists [ ] = { };
vector grads [ ] = { };
vector normals [ ] = { };

int hitpr = -1;
vector hituv = 0;

vector p = @P;
xyzdist ( 1, p, hitpr, hituv );
p = primuv ( 1, "P", hitpr, hituv );
vector grad = primuv ( 1, directionattrib, hitpr, hituv );
vector normal = primuv ( 1, "N", hitpr, hituv );
float cost = primuv ( 1, costattrib, hitpr, hituv );
float lastcost = cost;

append ( pos, p );
append ( dists, 0 );
append ( grads, grad );
append ( normals, normal );

float sumdist = 0;
while ( sumdist <= maxdist )
{
    p += normalize ( grad ) * stepsize;
    xyzdist ( 1, p, hitpr, hituv );
    p = primuv ( 1, "P", hitpr, hituv );
    grad = primuv ( 1, directionattrib, hitpr, hituv );
    normal = primuv ( 1, "N", hitpr, hituv );
    cost = primuv ( 1, costattrib, hitpr, hituv );
    
    if ( usecost && cost >= lastcost - tolerance )
    {
        stepsize *= stepsizemultiplier;
        if ( abs ( stepsize ) < tolerance )
            break;
    }
    else
    {
        dist = distance ( pos [ -1 ], p );
        if ( dist < tolerance )
            break;
        
        sumdist += dist;
        append ( pos, p );
        append ( dists, sumdist );
        append ( grads, grad );
        append ( normals, normal );
        
        lastcost = cost;
    }
}

if ( sumdist >= mindist )
{
    float m = 1.0 / sumdist;
    int count = len ( pos );
    int pts [ ] = { };
    for ( int i = 0; i < count; ++i )
    {
        int pt = addpoint ( 0, pos [ i ] );
        float s = dists [ i ] * m;
        vector color = chramp("color", s);
        
        vector grad = grads [ i ];
        vector normal = normals [ i ];
        vector bitangent = cross ( normal, grad );
        
        setpointattrib ( 0, "Cd", pt, color );
        setpointattrib ( 0, "grad", pt, grad );
        setpointattrib ( 0, "normal", pt, normal );
        setpointattrib ( 0, "bitangent", pt, bitangent );
        
        append ( pts, pt );
    }
    addprim ( 0, "polyline", pts );
}

removepoint ( 0, @ptnum );