- for parameters do you mean local maxima of animation curve?
you can use CHOPs for that for example Channel Wrangle:

float prev = chinput(C, I - 1);
float next = chinput(C, I + 1);

V = (prev <= V) && (next <= V);

- for heightfields you can do it in a similar way in Volume Wrangle, imply compare height of a current voxel to its neighbors and if all of them are smaller place a point or something (Volume Wrangle on isolated height volume):

float h = @height;
vector i = set(@ix, @iy, @iz);
vector is[] = array(i + {1,0,0}, i - {1,0,0}, i + {0,1,0}, i - {0,1,0}); // orthogonal neighbors
vector is2[] = array(i + {1,1,0}, i + {1,-1,0}, i + {-1,1,0}, i + {-1,-1,0}); // diagonal neighbors
append(is, is2);

int ismax = 1;
foreach(vector ni; is) {
    float nh = volumeindex(0, "height", ni);
    if (nh > h){
        ismax = 0;
        break;
    }
}

if (ismax) {
    int pt = addpoint(0, v@P);
    vector P = v@P + set(0, h, 0);
    setpointattrib(0, "P", pt, P);
}

removeprim(0, @primnum, 1);

Attachments:
ts_local_maxima_channel_and_heightfield.hipnc (184.0 KB)
ts_local_maxima_channel.png (9.4 KB)
ts_local_maxima_heightfield.png (99.8 KB)

Attachments:
Houdini_Volume_LocalMaxima2.PNG (1.8 MB)